mirror of
https://git.decapod.one/brethil/dotfiles
synced 2024-11-22 03:21:30 +01:00
98 lines
3.1 KiB
Bash
Executable File
98 lines
3.1 KiB
Bash
Executable File
#!/usr/bin/env zsh
|
|
# brethil, brutally copied from https://github.com/robbyrussell/oh-my-zsh/blob/master/tools/check_for_upgrade.sh
|
|
# This also runs antibody update"
|
|
# First version: 14 July 2017
|
|
# Rebased on upstream: 08 December 2020
|
|
|
|
|
|
local DOTFILES_UPDATEFILE=${DOTFILES}/.dotfiles-update
|
|
# Migrate .dotfiles-update file to $DOTFILES
|
|
if [[ -f ~/.dotfiles-update && ! -f "${DOTFILES_UPDATEFILE}" ]]; then
|
|
mv ~/.dotfiles-update "${DOTFILES_UPDATEFILE}"
|
|
fi
|
|
|
|
# Cancel update if:
|
|
# - the automatic update is disabled.
|
|
# - git is unavailable on the system.
|
|
if [[ -n $DISABLE_DOTFILES_AUTOUPDATE ]] || ! command -v git &>/dev/null; then
|
|
return
|
|
fi
|
|
|
|
|
|
function current_epoch() {
|
|
zmodload zsh/datetime
|
|
echo $(( EPOCHSECONDS / 60 / 60 / 24 ))
|
|
}
|
|
|
|
function _update_dotfiles_update() {
|
|
echo "LAST_EPOCH=$(current_epoch)" >! "${DOTFILES_UPDATEFILE}"
|
|
}
|
|
|
|
function update_dotfiles() {
|
|
(cd $DOTFILES; git pull -q --rebase && echo "Succesfully upgraded dotfiles" || echo "Could not upgrade dotfiles.")
|
|
(cd $DOTFILES/antidote && git pull --rebase || echo "Could not upgrade antidote")
|
|
vim -c 'PlugUpdate|PlugClean|qa!'
|
|
# update the zsh file
|
|
_update_dotfiles_update
|
|
}
|
|
|
|
() {
|
|
if [[ -n $DOTFILES_FORCEUPDATE ]]; then
|
|
update_dotfiles;
|
|
return;
|
|
fi
|
|
|
|
local epoch_target mtime option LAST_EPOCH
|
|
|
|
# Remove lock directory if older than a day
|
|
zmodload zsh/datetime
|
|
zmodload -F zsh/stat b:zstat
|
|
if mtime=$(zstat +mtime "$DOTFILES/update.lock" 2>/dev/null); then
|
|
if (( (mtime + 3600 * 24) < EPOCHSECONDS )); then
|
|
command rm -f "$DOTFILES/update.lock"
|
|
fi
|
|
fi
|
|
|
|
# Check for lock directory
|
|
if ! command mkdir "$DOTFILES/update.lock" 2>/dev/null; then
|
|
return
|
|
fi
|
|
|
|
# Remove lock directory on exit. `return 1` is important for when trapping a SIGINT:
|
|
# The return status from the function is handled specially. If it is zero, the signal is
|
|
# assumed to have been handled, and execution continues normally. Otherwise, the shell
|
|
# will behave as interrupted except that the return status of the trap is retained.
|
|
trap "
|
|
unset -f current_epoch _update_dotfiles_update update_dotfiles &>/dev/null
|
|
command rmdir '$DOTFILES/update.lock' &>/dev/null
|
|
return 1
|
|
" EXIT INT QUIT
|
|
|
|
# Create or update .zsh-update file if missing or malformed
|
|
if ! source "${DOTFILES_UPDATEFILE}" 2>/dev/null || [[ -z "$LAST_EPOCH" ]]; then
|
|
_update_dotfiles_update
|
|
return
|
|
fi
|
|
|
|
# Number of days before trying to update again
|
|
epoch_target=${UPDATE_DOTFILES_DAYS:-5}
|
|
# Test if enough time has passed until the next update
|
|
if (( ( $(current_epoch) - $LAST_EPOCH ) < $epoch_target )); then
|
|
return
|
|
fi
|
|
|
|
# Ask for confirmation before updating unless disabled
|
|
if [[ "$DISABLE_UPDATE_PROMPT" = true ]]; then
|
|
update_dotfiles
|
|
else
|
|
echo -n "[brethil-dotfiles] Would you like to update? [Y/n] "
|
|
read -r -k 1 option
|
|
case "$option" in
|
|
[yY$'\n']) update_dotfiles ;;
|
|
[nN]) _update_dotfiles_update ;;
|
|
*) echo -n "[brethil dotfiles] Skipping. Update using \`dotfiles_selfupdate\`" && echo ;;
|
|
esac
|
|
fi
|
|
}
|
|
unset -f current_epoch update_dotfiles _update_dotfiles_update
|